Another common request that I always find on some VFP forums is people wanting to draw some images, usually company logos over some pictures. This is really simple, as I'll show below.
For all the samples that I'll provide the VFPX logo will be drawn in some bigger pictures. To show all the flexibility that GDI+ can offer to us, some effects will be aplied to the logo.
SAMPLE 1: Draw Image without transformation
DO LOCFILE("System.App")
WITH _SCREEN.System.Drawing as xfcDrawing
LOCAL lcMainPict, lcLogoPict
LOCAL loMainBmp as xfcBitmap
LOCAL loLogoBmp as xfcBitmap
LOCAL loGfx as xfcGraphics
lcMainPict = GETPICT()
lcLogoPict = GETPICT()
loMainBmp = .Bitmap.FromFile(lcMainPict)
loLogoBmp = .Bitmap.FromFile(lcLogoPict)
loGfx = .Graphics.FromImage(loMainBmp)
*!* Example 1
*!* Original Image
*!* Position : Top Left
*!* Draw Logo without any transformation
loGfx.DrawImage(loLogoBmp, 0, 0)
loMainBmp.Save("c:\logo1.jpg", .Imaging.ImageFormat.Jpeg)
* Show image
RUN /N explorer.exe c:\logo1.jpg
ENDWITH
SAMPLE 2 : Convert the white background of our logo to transparent, using the Bitmap.MakeTransparent() function
DO LOCFILE("System.App")
WITH _SCREEN.System.Drawing as xfcDrawing
LOCAL lcMainPict, lcLogoPict
LOCAL loMainBmp as xfcBitmap
LOCAL loLogoBmp as xfcBitmap
LOCAL loGfx as xfcGraphics
lcMainPict = GETPICT()
lcLogoPict = GETPICT()
loMainBmp = .Bitmap.FromFile(lcMainPict)
loLogoBmp = .Bitmap.FromFile(lcLogoPict)
loGfx = .Graphics.FromImage(loMainBmp)
*!* Sample 2
*!* Converted selected color from logo with ALPHA 255 (Opaque) to TRANSPARENT ALPHA (0)
*!* Position : Top Right
* Force the White background from the logo to become transparent
loLogoBmp.MakeTransparent(.Color.White)
* Draw logo at the top right position of image
LOCAL x1, y1
x1 = loMainBmp.Width - loLogoBmp.Width
y1 = 0
loGfx.DrawImage(loLogoBmp, x1, y1)
loMainBmp.Save("c:\logo2.jpg", .Imaging.ImageFormat.Jpeg)
RUN /N explorer.exe c:\logo2.jpg
ENDWITH
SAMPLE 3 : Draw the logo aplying 25% transparency to the whole image.
The transparency is aplied to the whole image using a ColorMatrix. The transparency ratio that is aplied ranges from 0 (totally transparent) to 1 (totally opaque).
DO LOCFILE("System.App")
WITH _SCREEN.System.Drawing as xfcDrawing
LOCAL lcMainPict, lcLogoPict
LOCAL loMainBmp as xfcBitmap
LOCAL loLogoBmp as xfcBitmap
LOCAL loGfx as xfcGraphics
lcMainPict = GETPICT()
lcLogoPict = GETPICT()
loMainBmp = .Bitmap.FromFile(lcMainPict)
loLogoBmp = .Bitmap.FromFile(lcLogoPict)
loGfx = .Graphics.FromImage(loMainBmp)
*!* Sample 3
*!* Draw the logo aplying 25% transparency to the whole image
*!* Position: Bottom Left
* The transparency is aplied to the whole image
* Define the transparency ratio that will be aplied
* This parameter ranges from 0 (totally transparent) to 1 (totally opaque)
LOCAL lnTranspRatio
lnTranspRatio = 0.25 && 25%
* Create a ColorMatrix that will have the transformations information
* The position (4,4) of the matrix is responsible for the opacity
LOCAL loClrMatrix AS xfcColorMatrix
loClrMatrix = .Imaging.ColorMatrix.New( ;
1, 0, 0, 0 , 0, ;
0, 1, 0, 0 , 0, ;
0, 0, 1, 0 , 0, ;
0, 0, 0, lnTranspRatio, 0, ;
0, 0, 0, 0 , 0)
* Create an Image Attributes object to create the effects based in our ClrMatrix
LOCAL loAttr AS xfcImageAttributes
loAttr = .Imaging.ImageAttributes.New()
loAttr.SetColorMatrix(loClrMatrix)
* We need to create a rectangle that will contain the coordinates and size of the transformed logo
LOCAL loRect as xfcRectangle
loRect = .Rectangle.New()
loRect.X = 0
loRect.Y = loMainBmp.Height - loLogoBmp.Height
loRect.Width = loLogoBmp.Width
loRect.Height = loLogoBmp.Height
* Draw the transformed image using the rectangle and ImgAttributes/ClrMatrix
loGfx.DrawImage(loLogoBmp, loRect, loLogoBmp.GetBounds(), .GraphicsUnit.Pixel, loAttr)
loMainBmp.Save("c:\logo3.jpg", .Imaging.ImageFormat.Jpeg)
RUN /N explorer.exe c:\logo3.jpg
ENDWITH
SAMPLE 4 : Draw the logo with transparent background with 50% global transparency.
Aply 100% transparency to the white color, to eliminate the background
Draw the logo aplying 50% transparency to the whole image, similar to the previous sample.
DO LOCFILE("System.App")
WITH _SCREEN.System.Drawing as xfcDrawing
LOCAL lcMainPict, lcLogoPict
LOCAL loMainBmp as xfcBitmap
LOCAL loLogoBmp as xfcBitmap
LOCAL loGfx as xfcGraphics
lcMainPict = GETPICT()
lcLogoPict = GETPICT()
loMainBmp = .Bitmap.FromFile(lcMainPict)
loLogoBmp = .Bitmap.FromFile(lcLogoPict)
loGfx = .Graphics.FromImage(loMainBmp)
*!* Sample 4
*!* Aply 100% transparency to the white color, to eliminate the background
*!* Draw the logo aplying 50% transparency to the whole image
*!* Position: Top Left
* First step: eliminate the white background
loLogoBmp.MakeTransparent(.Color.White)
* Define the transparency ratio that will be aplied
* This parameter ranges from 0 (totally transparent) to 1 (totally opaque)
LOCAL lnTranspRatio
lnTranspRatio = 0.50 && 50%
* Create a ColorMatrix that will have the transformations information
* The position (4,4) of the matrix is responsible for the opacity
LOCAL loClrMatrix AS xfcColorMatrix
loClrMatrix = .Imaging.ColorMatrix.New( ;
1, 0, 0, 0 , 0, ;
0, 1, 0, 0 , 0, ;
0, 0, 1, 0 , 0, ;
0, 0, 0, lnTranspRatio, 0, ;
0, 0, 0, 0 , 0)
* Create an Image Attributes object to create the effects based in our ClrMatrix
LOCAL loAttr AS xfcImageAttributes
loAttr = .Imaging.ImageAttributes.New()
loAttr.SetColorMatrix(loClrMatrix)
* We need to create a rectangle that will contain the coordinates and size of the transformed logo
LOCAL loRect as xfcRectangle
loRect = .Rectangle.New()
loRect.X = 0
loRect.Y = 0
loRect.Width = loLogoBmp.Width
loRect.Height = loLogoBmp.Height
* Draw the transformed image using the rectangle and ImgAttributes/ClrMatrix
loGfx.DrawImage(loLogoBmp, loRect, loLogoBmp.GetBounds(), .GraphicsUnit.Pixel, loAttr)
loMainBmp.Save("c:\logo4.jpg", .Imaging.ImageFormat.Jpeg)
RUN /N explorer.exe c:\logo4.jpg
ENDWITH