Using some of the techniques presented in my previous posts, (read Gradient Backgrounds in your forms with GDI+), I've created a very simple subclass of the commandbutton object, in order to create gradient background effects.
Please take note that this is an unfinished class. I'm posting it here at this moment to show to people that we can obtain very cool effects using GDI+.
This is how the form looks in development mode:
Below you can see the form running, when GDI+ creates the backgrounds.
Properties that you need to fill to have the desired results:
Caption, FontBold, FontUnderline, FontItalic, FontStrikeThru
Picture,
BackColor (with the main color to be used as background)
GradientMode (0 = NO Gradient 1 = Vertical-Default 2 = Horizontal 3 = Diagonal1 4 = Diagonal2)
How the class was created:
I used the CommandButton Base class, to make it have the most common usage and understanding possible, making the development mode the most seemed to the result obtained when running the form.
In the INIT event of the class, it verifies the gradient direction, and creates a LinearGradient Brush, using the color defined in the BackColor property of the object. The second color was set to white as default. Then it draws a rectangle using this brush in a picture just created, that has the same dimensions of the CommandButton.
The next step is to check if there is a picture assigned to the button; if yes, draw it to the left side, centered in the vertical.
If the Caption property was set, then draw the string, centered in horizontal and vertical.
In this example I'm only using GIFs with transparent background, so that the background is preserved..
The codes
The main code stays in the INIT event of the CommandButton subclass:
WITH This
LOCAL lcGradFile, lnGradMode, lnGradPixels, x1, y1, x2, y2, lnWidth, lnHeight
lnGradMode = .GradientMode
IF lnGradMode = 0
RETURN && No Gradient Background !
ENDIF
lcGradFile = ADDBS(SYS(2023))+SYS(2015)+".bmp"
.cTempGradFile = lcGradFile
LOCAL lcPicture, lcCaption, lnRGBColor1
lcPicture = .Picture
lcCaption = .Caption
lnRGBColor1 = .BackColor
lnWidth = .Width
lnHeight = .Height
DO CASE
CASE lnGradMode = 1 && Vertical
y1 = 0
x2 = 1
y2 = lnHeight
CASE lnGradMode = 2 && Horizontal
y1 = 0
x2 = lnWidth
y2 = 1
CASE lnGradMode = 3 && Diagonal TopLeft -> BottomRight
y1 = 0
x2 = lnWidth
y2 = lnHeight
CASE lnGradMode = 4 && Diagonal BottomLeft -> TopRight
y1 = lnHeight
x2 = lnWidth
y2 = 0
ENDCASE
* Create Gradient Image
SET CLASSLIB TO HOME() + "ffc/_gdiplus.vcx" ADDITIVE
* Create a colorObject and store ARGB color values to variables
LOCAL loClr AS GpColor OF HOME() + "ffc/_gdiplus.vcx"
LOCAL lnColor1, lnColor2
loClr = CREATEOBJECT("gpColor")
loClr.FoxRGB = lnRGBColor1
lnColor1 = loClr.ARGB
loClr.FoxRGB = RGB(255,255,255) && White
lnColor2 = loClr.ARGB
* Create a bitmap
LOCAL loBmp AS GpBitmap OF HOME() + "ffc/_gdiplus.vcx"
loBmp = CREATEOBJECT("gpBitmap")
loBmp.Create(.Width, .Height)
* Get a bitmab graphics object
LOCAL loGfx AS GpGraphics OF HOME() + "ffc/_gdiplus.vcx"
loGfx = CREATEOBJECT("gpGraphics")
loGfx.CreateFromImage(loBmp)
* Declare API
DECLARE LONG GdipCreateLineBrushI IN GDIPLUS.DLL ;
STRING point1, STRING point2, ;
LONG color1, LONG color2, ;
LONG wrapMode, LONG @lineGradient
* Get a gradient brush
LOCAL loBrush AS GpBrush OF HOME() + "ffc/_gdiplus.vcx"
LOCAL hBrush && Brush Handle
hBrush = 0
GdipCreateLineBrushI(BINTOC(0,"4rs") + BINTOC(y1,"4rs"), ;
BINTOC(x2,"4rs") + BINTOC(y2,"4rs"), ;
lnColor1, lnColor2, 0, @hBrush)
loBrush = CREATEOBJECT("gpBrush")
loBrush.SetHandle(hBrush, .T.)
* Fill the bitmap with our gradient
loGfx.FillRectangle(loBrush,0,0,.Width, .Height)
* Draw the Desired picture
IF NOT EMPTY(lcPicture)
LOCAL loPict AS GpImage OF HOME() + "ffc/_gdiplus.vcx"
loPict = CREATEOBJECT("gpImage")
loPict.CreateFromFile(lcPicture)
x1 = 1
y1 = (.Height - loPict.ImageHeight) / 2
loGfx.DrawImageAt(loPict,x1, y1)
ENDIF
* Draw the Caption
#DEFINE fontstyleregular 0
#DEFINE fontstylebold 1
#DEFINE fontstyleitalic 2
#DEFINE fontstyleunderline 4
#DEFINE fontstylestrikeout 8
#DEFINE unitworld 0
#DEFINE unitdisplay 1
#DEFINE unitpixel 2
#DEFINE unitpoint 3
#DEFINE unitinch 4
#DEFINE unitdocument 5
#DEFINE unitmillimeter 6
IF NOT EMPTY(.Caption)
LOCAL lnFontStyle
lnFontStyle = fontstyleregular + ;
IIF(.FontBold, fontstylebold, 0) +;
IIF(.FontItalic, fontstyleitalic, 0) +;
IIF(.FontUnderline, fontstyleunderline, 0) +;
IIF(.FontStrikethru, fontstylestrikeout, 0)
LOCAL loFont AS GpFont OF HOME() + "ffc/_gdiplus.vcx"
loFont = NEWOBJECT('GpFont', HOME() + 'ffc/_gdiplus.vcx')
loFont.CREATE( .FontName ; && font name
, .FontSize ; && size in units below
, lnFontStyle ; && fontStyle
, unitPOINT ) && units
* Create SolidBrush with the ForeColor
LOCAL loSolidBrush AS GpSolidBrush OF HOME() + "ffc/_gdiplus.vcx"
loSolidBrush = NEWOBJECT('GpSolidBrush', HOME() + 'ffc/_gdiplus.vcx','',0)
loClr.FoxRGB = .ForeColor
loSolidBrush.BrushColor = loClr
* Measure the Height of the caption to calculate vertical position
LOCAL loStringSize AS GpSize OF HOME() + 'ffc/_gdiplus.vcx'
lostringsize = loGfx.MeasureStringA(.Caption, loFont)
lnPictWidth = IIF(EMPTY(lcPicture), 0,loPict.ImageWidth)
x1 = lnPictWidth + ((.Width - lnPictWidth - 1) - loStringSize.w) / 2
y1 = (.Height - lostringsize.h) / 2
* Create PointF with the position of Caption
lcTextPoint = BINTOC(X1,'F') + BINTOC(Y1,'F')
loGfx.DrawStringA(.Caption, loFont, lctextPoint, , loSolidBrush)
ENDIF
* Save image to file
loBmp.SaveToFile(lcGradFile,"image/bmp")
.Picture = lcGradFile
ENDWITH
RETURN
In DESTROY event, we just delete the temporary image created
IF This.GradientMode = 0
RETURN && No Gradient Background !
ENDIF
WITH This
IF FILE(.cTempGradFile)
CLEAR RESOURCES (.cTempGradFile)
ERASE (.cTempGradFile)
ENDIF
ENDWITH
To be improved:
- PicturePosition - at this moment, it will always work as "1 - left of caption, centered relative to caption". VFP9 brings 14 position options, this can be done easily in a future version.
- add another property to receive the 2nd color ( at this moment, white - RGB(255,255,255) is default)
- permit to create 3 color gradients, allowing for example: blue - white - blue
- to deal with a disabled commandbuttons. Please send suggestions / or pictures showing how the control should look when disabled !
- permit to receive any image, and create the transparency of the backgrounds.
The icons that I used to create this example were taken from http://www.iconbazaar.com , where you can find many cool GIFs
You can download the source code from the first version of the class from here:
07/19/2006 - UPDATED VERSION OF THE CLASS
I've received many suggestions, and created a new version of the class, adding many other features.
You can download the most recent version of the class and some Forms using it from this link :
http://weblogs.foxite.com/files/cesarchalom/gradobjects/gradobjects.zip
When running the form "testGradButtons", please pass the mouse over the buttons and also click the "DISABLE" button.
Here are some screenshots of the new version:
As always, please send your comments, suggestions and fixes !