Foxite.COM Community Weblog

Drawing shapes with GdiPlusX is super easy, and we can very easilly transport this to solve some of our chart needs.

In this post I'm sending you a very primitive sample for creating Circular Gauge charts. Obviously I hope to apply the techniques shown here in FoxCharts. But FoxCharts is getting big, and I confess that learning from the methods in FoxCharts may not be easy for people that are not that familiar with GdiPlusX.

Please note that this is an unfinished sample. I'm posting it here to let people see that drawing is not that complicated. Just using some imagination, merging it with some geometrical thoughts, and voilá !

Download the Gauge sample, unzip and run TESTGAUGE.SCX ! I'm including the GdiPlusX sources to let everybody immediately run the samples.

Notice that you can control the colors of the background and pointer.

The pointer shape can be modified too. Play with all the spinners to modify the shape and size! And please tell me which you like most. I'll apreciate receiving some image samples with some desired gauge charts.

Below is the relevant code for the circular gauge drawing. You'll find it in the "BeforeDraw()" event of the ImageCanvas class. It extracts the information from the form controls, and it's very easy to adapt it to your needs.

LOCAL lnAngle, lnBaseW, lnBaseX, lnBaseY, lnTopW, lnHeightPercent, lnTopY
LOCAL lnType, lnPointClr, lnBackClr, lnTicks
lnTicks = Thisform.SpnTicks.Value
lnType = Thisform.OptShape.Value
lnAngle = Thisform.SpnAngle.Value
lnBaseW = Thisform.SpnBottomW.Value
lnTopW = Thisform.SpnTopW.Value
lnBaseX = This.Width/2 -lnBaseW/2
lnBaseY = This.Height/2
lnHeightPercent = Thisform.SpnHeight.Value / 100
lnTopY = lnBaseY - (lnBaseY * lnHeightPercent) + lnTopW / 2
lnPointClr = Thisform.ShpPointerColor.BackColor
lnBackClr = Thisform.ShpBackColor.BackColor
LOCAL loGfx as xfcGraphics
loGfx = This.oGfx

WITH _Screen.System.Drawing
   LOCAL loBrush as xfcSolidBrush
   loBrush = .SolidBrush.New(.Color.FromRGB(lnPointClr))

   loGfx.Clear(.Color.FromRGB(Thisform.BackColor))

   * Create a Shape for the pointer
   LOCAL loPath as xfcGraphicsPath
   loPath = .Drawing2D.GraphicsPath.New()
   loPath.StartFigure()
   loGfx.FillEllipse(.SolidBrush.New(.Color.FromRGB(lnBackClr)), ;
         This.Rectangle)

   IF lnType = 1
      loPath.AddArc(lnBaseX, This.Height/2 -lnBaseW/2, lnBaseW, lnBaseW, 0, 180)
   ENDIF

   loPath.AddLine(lnBaseX, lnBaseY, This.Width/2 - lnTopW/2, lnTopY)
   IF lnType = 1
      LOCAL laPoints(3)
      laPoints(1) = .Point.New(This.Width/2 - lnTopW/2, lnTopY)
      laPoints(2) = .Point.New(This.Width/2 , lnTopY - lnTopW / 2)
      laPoints(3) = .Point.New(This.Width/2 + lnTopW/2, lnTopY)
      loPath.AddCurve(@laPoints)
   ENDIF

   loPath.AddLine( This.Width/2 + lnTopW/2, lnTopY, lnBaseX + lnBaseW, lnBaseY)
   loPath.CloseFigure()

   * Rotate the shape pointer
   loGfx.TranslateTransform(This.Width/2, This.Height/2)
   loGfx.RotateTransform(lnAngle)
   loGfx.TranslateTransform(- This.Width/2, - This.Height/2)

   * Draw the pointer
   loGfx.FillPath(loBrush, loPath)

   * Restore the original Gfx rotation state
   loGfx.ResetTransform()
 

   IF lnTicks > 0
      FOR lnAngle = 0 TO 360 STEP 360 / lnTicks

         * Rotate the Gfx
         loGfx.TranslateTransform(This.Width/2, This.Height/2)
         loGfx.RotateTransform(lnAngle)
         loGfx.TranslateTransform(- This.Width/2, - This.Height/2)

         * Draw the ticks
         loGfx.DrawLine(.Pens.Black, This.Width/2, 0, This.Width/2, 10)

         * Restore the original Gfx rotation state
         loGfx.ResetTransform()
      ENDFOR 
   ENDIF

ENDWITH

Enjoy !!!

This is just an update for an old post with the same title. Erik Gomez and Russel Campbell had some problems on the conversions of some specific PNG images, so I recoded this function, this time using a safer code.

NEW UPDATE:

Thanks to Bernard Bout and Craig Boyd, I've updated the code below. In fact it contained a small bug, that was not adjusting the White colors. Now it seems to be working nice. Thanks !

This runs a little bit slower than the other aproach, but in my tests, the success was 100%.

The function below converts any button image to a BMP to be used in VFP forms.

There are lots of cool and free icons available on the web, but the vast majority are in .ICO, GIF or PNG image formats, that are not very familiar and reliable to be used in VFP. For us, the best image format, for a lot of reasons, is the BMP format.

Some transformations are needed to make this BMP to show exactly how we desire, specially when converting source images in a PNG, GIF or ICO formats.

VFP shows the pure white - RGB(255,255,255) as transparent in our buttons and image objects. The code below first converts the original whites to RGB(254,254,254) that is visually the same, but does not become transparent, and eliminates the need to create a mask image (.MSK) and next, converts the background color of the original bitmap to pure white, that will show transparent in VFP forms.

For more details, please check these prior posts:

BMPs with Transparent Backgrounds

How to put one image over another in a form

IMPORTANT
Requires VFP9 and GdiPlusX to run. 
Please make sure that you have the latest version, because this sample may be using some functions that were added or fixed recently.
http://www.codeplex.com/VFPX/Wiki/View.aspx?title=GDIPlusX&referringTitle=Home

Save the program below as BUTTON2BMP.PRG, and call it this way:

Button2Bmp(GETPICT(), "c:\NewIcon.bmp")

When you compile this program in your executable, please don't forget to remove the LOCFILE() command, and just use a DO System.App instead

LPARAMETERS tcSourceFile, tcDestFile

* tcSourcefile = GETPICT()
* tcDestFile = FORCEEXT(tcSourceFile, "Bmp")

DO LOCFILE("System.App")

LOCAL loBmp AS xfcBitmap
LOCAL loGfx AS xfcGraphics
LOCAL loBorderClr AS xfcColor
LOCAL loRect AS xfcRectangle
LOCAL loAttr AS xfcImageAttributes
LOCAL loColorMap AS xfcColorMap
LOCAL loDestBmp as xfcBitmap
 
WITH _SCREEN.SYSTEM.Drawing
	loColorMap = .Imaging.ColorMap.New()
	loAttr = .Imaging.ImageAttributes.New()
	loBmp = .Bitmap.FromFile(tcSourceFile)
	loGfx = .Graphics.FromImage(loBmp)

	loDestBmp = .Bitmap.New(loBmp.Width, loBmp.Height, .Imaging.PixelFormat.Format24bppRGB)
	loDestGfx = .Graphics.FromImage(loDestBmp)

	* Clear the new bitmap
	loDestGfx.Clear(.Color.White)

	* By Craig Boyd - For enhancing the smoothless and quality
	loDestGfx.SmoothingMode     = .Drawing2D.SmoothingMode.HighQuality 
	loDestGfx.InterpolationMode = .Drawing2D.InterpolationMode.HighQualityBicubic
	loDestGfx.PixelOffsetMode   = .Drawing2D.PixelOffsetMode.HighQuality

	loRect = loBmp.GetBounds()

	* Get the top left pixel color, presuming this color is the BackGround color to become transparent
	* For our BMP case, this will become PURE WHITE - RGB(255,255,255)
	* that becomes transparent when used in VFP objects
	loBorderClr = loBmp.GetPixel(0,0)

	* Convert original Whites RGB(255,255,255) to OFF WHITE - RGB(254,254,254)
	* this way, the whites will remain without the need of a mask
	loColorMap.OldColor = .Color.White
	loColorMap.NewColor = .Color.FromARGB(255,254,254,254)

	loAttr.SetRemapTable(loColorMap)
	loDestGfx.DrawImage(loBmp, loRect, loRect, .GraphicsUnit.Pixel, loAttr)

	* Next step, convert the borders to pure White, RGB(255,255,255) that will become transparent in buttons
	loColorMap.OldColor = loBorderClr
	loColorMap.NewColor = .Color.White
	loAttr.SetRemapTable(loColorMap)

	loDestGfx.DrawImage(loDestBmp, loRect, loRect, .GraphicsUnit.Pixel, loAttr)

	loDestBmp.Save(tcDestFile, .Imaging.ImageFormat.Bmp)
ENDWITH

As I've shown in a previous post from last year, this is totally possible for us in VFP, using the GdiPlusX library together with ReportListeners, remember?

BUT I've been receiving some emails about the Full-Justified ReportListener I published last year.

It did not deal with the possibility of multipage reports. In fact, when a string that had to be printed in FullJustified mode had to be divided in more than one page, in the next page the whole string was redrawn.

To solve this, I needed to make some adjustments in the report listener source, more specifically in the "Render" event, in order to deal with the parameters "nObjectContinuationType" and "cContentsToBeRendered". I had totally missed them. In the first version, I was only using the "Text" property that I retrieved in the "EvaluateContents" method. The first tells us if the text could be totally drawn, or partially. The 2nd, brings the text that is to be drawn, not the whole text.

It's amazing how we can control our output with all these new enhancements from the VFP9 Reporting System. In fact, we can control almost everything !

It's a pity I couldn't explore this tool as much as I would like, the possibilities seem to be infinite.

In HELP I found all the info I needed to fix it:

• nObjectContinuationType
  * Indicates the current continuation state for the rendered element. When layout elements span pages, they are rendered in multiple sections (once for each page).
  * Value  Continuation Type 
  *   0    Complete (no continuation).
  *   1    Start of layout element occurrence, will not finish on the current page.
  *   2    Mid-element, neither started nor finished on the current page.
  *   3    End of element, completed on the current page.

• cContentsToBeRendered
  * Indicates the text to be rendered for Expression (Field) and Label layout elements.
  * If your derived class sends the text value through some additional processing, such as storage in a table, you can use the STRCONV() function, and its optional regional script parameter, to convert the string to DBCS first. For more information, see STRCONV( ) Function.

Some important tweaks and fixes were needed in the GdiPlusX library too, more specifically in the xfcGraphics.DrawStringJustified function. I added to it a new parameter, "tlJustifyLast", in order fo force the justifying in the last sentence. This is for the case of reports, when an unfinished sentence needs to be justified as well.

The source code is below, you can adapt it to your needs !

The idea is to add a "<FJ>" tag in the USER tab or in the beginning of any string from a textbox in a report, to tell the ReportListener that it will draw the text using the DRAWSTRINGJUSTIFIED method from GdiPlusX. Special thanks to Victor Espinoza, from Miami, FL, for his important feedback, suggestions and fixes.

The "FullJustifyListener" performs the following actions:

- Initializes GdiPlusX

- Creates a GDI+ Graphics object that will be used to draw in the report

- Stores in an array the required information needed to draw the string(Font, Size, Style and Color)

- Before Rendering the string, checks if the "<FJ>" tag is at the beginning of text or at the "USER" tab in the report designer - if yes, draws the string using the new method.

Here are the steps for you to bring this to your reports:

1 - Download the updated GdiPlusX library - the System.App file

VERY IMPORTANT - READ THIS !

This report listener needs the updated version of the GdiPlusX main file of the library, "System.App". As it will take some time till a new version will be released, I've uploaded this file separately, so that people can try this feature from now.

Go to this link: http://www.codeplex.com/VFPX/Release/ProjectReleases.aspx?ReleaseId=8606

And download the file "GdiPlusX Updated System.App for FullJustified purposes"

If you prefer, this file is found in the downloadable source code from this article.

2 - Save the ReportListener:

Please Copy and Paste the code below, and save it as FJLISTENER.PRG in the samples folder of GdiPlusX 

* Program : FJLISTENER.PRG
* Version : 2.0
* Purpose : Provides a Report Listener that allows rendering text in
* Full Justify alignment.
* Authors : Cesar Ch http://weblogs.foxite.com/vfpimaging
* Class based on article "Listening to a report" by Doug Hennig
* New tweaked version allows drawing strings that need to be divided in more than one page

* Special thanks to Victor Espinoza 
* http://msdn2.microsoft.com/en-us/library/ms947682.aspx

DEFINE CLASS FullJustifyListener AS FXListener
oGDIGraphics = NULL
nSaveGraphicsHandle = 0
nTimes = 1
DIMENSION aRecords[1]
 
* Before we run the report, go through the FRX and store information about any
* field with our expected directive in its USER memo into the aRecords array.
FUNCTION BEFOREREPORT
   DODEFAULT()
   * Check if we already have the "System" object in "_Screen"
   IF NOT PEMSTATUS(_Screen,"System",5)
      DO LOCFILE("System.App")
   ENDIF
   WITH This
      .oGDIGraphics = _SCREEN.SYSTEM.Drawing.Graphics.New()
      .SetFRXDataSession()
      DIMENSION .aRecords[reccount(), 13]
      SCAN FOR "<FJ>" $ UPPER(User)
         .aRecords[recno(), 13] = "FJ"
      ENDSCAN
     .ResetDataSession()
   ENDWITH
ENDFUNC

FUNCTION BEFOREBAND(nBandObjCode, nFRXRecNo)
   This.SharedGDIPlusGraphics = This.GDIPLUSGRAPHICS
   This.oGDIGraphics.Handle = This.SharedGDIPlusGraphics
   DODEFAULT(nBandObjCode, nFRXRecNo)
ENDFUNC
 
PROCEDURE RENDER(tnFRXRecNo,;
   tnLeft,tnTop,tnWidth,tnHeight,;
   nObjectContinuationType, ;
   cContentsToBeRendered, GDIPlusImage)

   LOCAL lcText, llFlag
   llFlag = .F.
   lcText = This.aRecords(tnFRXRecNo,1)

   IF (VARTYPE(lcText) = "C" AND LEFT(lcText,4) = "<FJ>") OR ;
      (VARTYPE(This.aRecords(tnFRXRecNo,13)) = "C" AND This.aRecords(tnFRXRecNo,13) == "FJ")

      IF nObjectContinuationType > 0

      * nObjectContinuationType
      * -----------------------
      * Indicates the current continuation state for the rendered element. When layout elements span pages, they are rendered in multiple sections (once for each page).
      * Value Continuation Type
      * 0 Complete (no continuation).
      * 1 Start of layout element occurrence, will not finish on the current page.
      * 2 Mid-element, neither started nor finished on the current page.
      * 3 End of element, completed on the current page.

      * cContentsToBeRendered
      * ---------------------
      * Indicates the text to be rendered for Expression (Field) and Label layout elements.
      * If your derived class sends the text value through some additional processing, such as storage in a table, you can use the STRCONV() function, and its optional regional script parameter, to convert the string to DBCS first. For more information, see STRCONV( ) Function.

         lcText = STRCONV(cContentsToBeRendered,6)

            IF INLIST(nObjectContinuationType, 1, 2)
               llFlag = .T.
            ENDIF
         ENDIF
 
         IF UPPER(LEFT(lcText,4)) = "<FJ>"
            lcText = SUBSTR(lcText,5) && Remove the <FJ> tag from string
         ENDIF

         WITH _SCREEN.SYSTEM.Drawing

         This.oGDIGraphics.Handle = This.GDIPlusGraphics
         *!* Create a GDI+ Rectangle which specifies where on the
         *!* surface we're drawing the text.
         LOCAL loRectF as xfcRectangleF
         loRectF = .RectangleF.New(tnLeft, tnTop, tnWidth, tnHeight)

         LOCAL loFont as xfcFont
         loFont = .Font.New(This.aRecords(tnFRXRecNo,2) ;
            , This.aRecords(tnFRXRecNo,4), This.aRecords(tnFRXRecNo,3) ;
            , .GraphicsUnit.Point)

         * Retrieve colors for the background
         LOCAL lnRed, lnGreen, lnBlue, lnAlpha
         lnRed = This.aRecords[tnFRXRecno,5]
         lnGreen = This.aRecords[tnFRXRecno,6]
         lnBlue = This.aRecords[tnFRXRecno,7]
         lnAlpha = This.aRecords[tnFRXRecno,8]
         LOCAL loBackBrush as xfcSolidBrush
         loBackBrush = .SolidBrush.New(;
            .Color.FromArgb(lnAlpha,lnRed, lnGreen, lnBlue))

         This.oGdiGraphics.FillRectangle(loBackBrush, tnLeft, tnTop, tnWidth, tnHeight)

         * Retieve colors for the Text
         lnRed = This.aRecords[tnFRXRecno,9]
         lnGreen = This.aRecords[tnFRXRecno,10]
         lnBlue = This.aRecords[tnFRXRecno,11]
         lnAlpha = This.aRecords[tnFRXRecno,12]
         LOCAL loTextBrush as xfcSolidBrush
         loTextBrush = .SolidBrush.New(;
            .Color.FromArgb(lnAlpha,lnRed, lnGreen, lnBlue))

         This.oGdiGraphics.DrawStringJustified(lcText, loFont, loTextBrush, loRectF, llFlag)

         ENDWITH
      ELSE
      *!* If we're not drawing a full justified string,
      *!* let Fox draw the text as usual.
         DODEFAULT(tnFRXRecNo, tnLeft, tnTop, tnWidth, tnHeight, ;
            nObjectContinuationType, cContentsToBeRendered, GDIPlusImage)
      ENDIF

      *!* Since we already drew the text, we don't want the default
      *!* behavior to occur.
   NODEFAULT
ENDPROC

FUNCTION EvaluateContents(tnFRXRecno, toObjProperties)
   * Get the FRX data
   This.aRecords[tnFRXRecno,1] = toObjProperties.Text
   This.aRecords[tnFRXRecno,2] = toObjProperties.FontName
   This.aRecords[tnFRXRecno,3] = toObjProperties.FontStyle
   This.aRecords[tnFRXRecno,4] = toObjProperties.FontSize
   This.aRecords[tnFRXRecno,5] = toObjProperties.FillRed
   This.aRecords[tnFRXRecno,6] = toObjProperties.FillGreen
   This.aRecords[tnFRXRecno,7] = toObjProperties.FillBlue
   This.aRecords[tnFRXRecno,8] = toObjProperties.FillAlpha
   This.aRecords[tnFRXRecno,9] = toObjProperties.PenRed
   This.aRecords[tnFRXRecno,10] = toObjProperties.PenGreen
   This.aRecords[tnFRXRecno,11] = toObjProperties.PenBlue
   This.aRecords[tnFRXRecno,12] = toObjProperties.PenAlpha
ENDFUNC

ENDDEFINE

3 - Update the report:

Below is a short tutorial for the beginners:

- Open any of your reports, that contains a field of more than one line that will receive the effect. Double-Click on that field, select the GENERAL tab, and add BEFORE your expression, this simple string: [  "<FJ>" +  ], like in the picture below.

Another better option is to add the tag to the USER tab, that is available only in VFP9 Report Designer. Just like before, double-click in the desired field, select the "OTHER" tab, then click on the "EDIT USER DATA" button, and add the <FJ> tag to the window, just like the picture below. This is the most recommended approach, because the original data will not be affected, and if one day you decide to stop using the report listener, your report data will not be affected.

4 - Run the report

* Tell VFP that we'll be using the new report features
SET REPORTBEHAVIOR 90
LOCAL loReportListener
loReportListener = CREATEOBJECT("FullJustifyListener")
loReportListener.ListenerType = 1
REPORT FORM YourReport OBJECT loReportListener

Below a last screenshot, showing the of the continued field issue solved:

Enjoy !!!

CLICK HERE TO DOWNLOAD THE SOURCE CODE AND SAMPLE FROM THIS ARTICLE

Here's a new release of FoxCharts

https://www.codeplex.com/Release/ProjectReleases.aspx?ProjectName=VFPX&ReleaseId=13477

Prerequisites:
Visual FoxPro 9 and the GdiPlusX library from VFPX 

As you can see, 2 new charts are now available:

- Stacked Area

- Cylinder

• The StackedArea chart can be defined using the "ChartType" property, that must be set to the numeric 10
• The Cylinder chart is derived from the original Bars chart. To have it, select ChartType for the bar option, and then set the BarType property to numeric 1 (0 = Bar Default; 1 = Cylinder)
  

Apart from this, many other important modifications were applied:

The main difference is that now FoxCharts' base class is a Container, that contains the GdiPlusX ImageCanvas, and the legend objects, responsible for drawing all the text needed.

Now we can customize any of those labels in lots of ways. Every piece of text, legend in the chart now has the following properties:

Alignment - 0 Left; 1 Right; 2 Center
BackColor
BackColorAlpha - this is cool, (0-255) determines the transparency of the background of the label
Caption
FontBold
FontItalic
FontName
FontSize
FontStrikethru
FontUnderline
ForeColor
ForeColorAlpha - determines the transparency of the label

The legends are represented by the following objects:

Title
SubTitle
XAxis
XAxisLegend2
YAxis
ShapeLegend
ScaleLegend
SideLegend

This way, every piece of text in the chart can be fully customized, not only the font, but the backcolor and the alpha (transparency). Now you can also change the alignment of the text, for example, to set the title to Right Alignment, all you have to do is to:

Thisform.FoxCharts1.Title.Alignment = 1 && Right

I still need to remind you that this is still a preview version, destined for people that are interested in helping testing this tool.



Please continue sending your suggestions and feedback!
It is really very appreciated

https://www.codeplex.com/Release/ProjectReleases.aspx?ProjectName=VFPX&ReleaseId=13477

Contains the ALPHA version of the FoxCharts project.

Unzip the file and run the form ChartsSample to see how it works.

This version also distributes the two main files from GdiPlusX - System.app and GdiPlusX.vcx.
If you are already a GdiPlusX user, you can use your own GdiPlusX version.
Just make sure to be using the latest GdiPlusX version.

GdiPlusX is also a VFPX project. For more information, please visit the GdiPlusX page at VFPX.


More information and pictures about this project can be obtained at the VFPIMAGING weblog:

http://weblogs.foxite.com/vfpimaging/archive/2008/04/04/5919.aspx

http://weblogs.foxite.com/vfpimaging/archive/2008/04/24/6040.aspx


This new release contains lots of enhancements:

Chart Types
- Bar charts
- Multiple bars
- Stacked bars

- Pie
- Doughnut

- Lines
- Area
- Stacked Area
- Points and Shapes


Color variations:
- Basic colors
- Custom colors
- Gradient colors
- Random colors
- Monochrome
- Gradient or solid colors


Legends in many places: Axys, shapes, side legends

Scales

Customize:
- Titles
- Subtitles
- Backgrounds (solid or gradient)
- Fonts
- Colors

One fix for VFP9 SP2 has just been released:

http://support.microsoft.com/kb/948528/en-us

Good news is when they say: "This hotfix may receive additional testing. Therefore, if you are not severely affected by this problem, we recommend that you wait for the next Visual FoxPro 9.0 service pack that contains this hotfix."

Till now I had seen many samples showing how we can make the Print button invisible from the Report Preview toolbar, but I had never seen the possibility to show it disabled.
Here's a sample, totally based in Emerson Reed's, from an old post in his great blog: A sample on how to add features to Report Listener - http://weblogs.foxite.com/emersonreed/archive/2006/09/13/A_sample_on_how_to_add_features_to_Report_Listener.aspx

It brings the possibility to hide completely the Print button or to disable it - just set the properties "PrintButtonVisible" and "PrintButtonEnabled". Apart from this, it also allows to change the tooltips from the buttons. For my case this is really helpful, in order to have the translated tooltips to my native language.

I've only added 7 or 8 lines of code all the sample comes from Emerson.
It was tricky to set the "enabled" property of the print button, because there's no property that allows us to set this, differently from the "Visible", that was allowed, using the property "AllowPrintfromPreview".
Even setting the property "Enabled" directly in the ExtensionHandler class below, the button still appeared enabled.

.cmdPrint.Enabled = .F. && Did not work

My solution was to use BINDEVENT, in order to control the behavior whenever the report previewer tried to change the "Enabled" property:

BINDEVENT(THIS.PreviewForm.Toolbar.CmdPrint,"Enabled",This,"Disabled",1)
 
Then, I added a custom function "Disabled", that forces the Print button to appear disabled:
 
PROCEDURE Disabled
   THIS.PreviewForm.Toolbar.cmdPrint.Enabled = .F.
ENDPROC

 

 
* See "Leveraging the default preview container" topic in HELP for more info
* Report Listener based on Emerson Reed's sample from
* http://weblogs.foxite.com/emersonreed/archive/2006/09/13/A_sample_on_how_to_add_features_to_Report_Listener.aspx

* Create a Report Listener object
Local loReportListener
loReportListener = Newobject("MyReportListener")
With loReportListener
   .ListenerType = 1 && Preview
   .PrintButtonVisible = .T.
   .PrintButtonEnabled = .F.
Endwith
 
* Run a report from the samples of VFP using the new report engine (object-assisted output)
REPORT FORM ;
   HOME() + 'Samples\Solution\Reports\colors.frx' ;
   OBJECT loReportListener
RETURN
 
 
 
* Custom Report Listener that adds some features
Define Class MyReportListener As FXLISTENER Of Addbs(Home()) + "FFC\_ReportListener.VCX"

* Public properties
PrintButtonVisible = .T.
PrintButtonEnabled = .T.
*
Procedure LoadReport
   DoDefault()
   With This
      If .ListenerType==1 And Not Vartype(.PreviewContainer)=="O"
         .ExtendPreviewContainer()
      Endif
   Endwith
Endproc
*
Function ExtendPreviewContainer
   Local loPreviewContainer
   loPreviewContainer = Null
   Do (_ReportPreview) With loPreviewContainer
   loPreviewContainer.AllowPrintfromPreview = This.PrintButtonVisible

   LOCAL loExtHandler
   loExtHandler = CREATEOBJECT("MyExtensionHandler")
   loExtHandler.DisablePrintButton = NOT This.PrintButtonEnabled

   loPreviewContainer.SetExtensionHandler(loExtHandler)
   This.PreviewContainer = loPreviewContainer
Endfunc
Enddefine

* Create a class that will extend Report Preview
Define Class MyExtensionHandler As Custom
   DisablePrintButton = .F.

Procedure Show(iStyle)
With This.PreviewForm
   With .Toolbar
   * Translate toolbar buttons ToolTips to Brazilian Portuguese language
   .cboZoom.ToolTipText = "Zoom"
   .cmdClose.ToolTipText = "Fechar a visualização"
   .cmdGoToPage.ToolTipText = "Ir para a página"
   .cmdPrint.ToolTipText = "Imprimir"
 
   IF This.DisablePrintButton
      * BINDEVENT(THIS.PreviewForm.Toolbar.CmdPrint, "Visible", This, "Invisible", 1)

      * Here we control the ENABLED property
      BINDEVENT(THIS.PreviewForm.Toolbar.CmdPrint, "Enabled", This, "Disabled", 1)
   ENDIF

   With .cntNext
      .cmdBottom.ToolTipText = "Última página"
      .cmdForward.ToolTipText = "Próxima página"
   Endwith

   With .cntPrev
      .cmdBack.ToolTipText = "Página anterior"
      .cmdTop.ToolTipText = "Primeira página"
   Endwith

   With .opgPageCount
      .opt1.ToolTipText = "Uma página"
      .opt2.ToolTipText = "Duas páginas"
      .opt3.ToolTipText = "Quatro páginas"
   Endwith
*
   Endwith
   .WindowState = 2 && Maximize report preview
   Endwith
   DoDefault(iStyle)

ENDPROC

* Here is the relevant code to disable the button
PROCEDURE Disabled
   THIS.PreviewForm.Toolbar.cmdPrint.Enabled = .F.
ENDPROC
*
Enddefine

Carlos alloatti has just published a new and very interesting article about image formats, I strongly recommend people to have a look at this new great work from Carlos.

http://www.ctl32.com.ar/articles/what_is_the_best_image_format_for_VFP.asp

Also, don't miss to visit his CTL32 site, full of really cool and useful classes:

http://www.ctl32.com.ar